クエリ1

PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
PREFIX ma:     <https://mediaarts-db.artmuseums.go.jp/data/property#>
SELECT ?アイテム ?ラベル
WHERE {
    ?アイテム schema:genre "マンガ雑誌単号" ;
    rdfs:label ?ラベル .
}
LIMIT 1000
                    

→SPARQLクエリサービスで実行する

クエリ2

PREFIX xsd:    <http://www.w3.org/2001/XMLSchema#>
PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
PREFIX ma:     <https://mediaarts-db.artmuseums.go.jp/data/property#>
PREFIX class:  <https://mediaarts-db.artmuseums.go.jp/data/class#>
SELECT
    ?マンガ雑誌単号ラベル ?開始ページ ?終了ページ ?分類・記事種別 ?タイトル
WHERE {
<https://mediaarts-db.artmuseums.go.jp/id/M535428> a class:MangaMagazineIssue ;
    schema:genre "マンガ雑誌単号" ;
    rdfs:label ?マンガ雑誌単号ラベル ;
    schema:hasPart [
        schema:genre ?分類・記事種別 ;
        schema:pageStart ?開始ページ ;
        schema:pageEnd ?終了ページ ;
        schema:alternativeHeadline ?タイトル ;
    ].
}
ORDER BY xsd:float(?開始ページ)
                    

→SPARQLクエリサービスで実行する

クエリ3

PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
PREFIX wdt:    <http://www.wikidata.org/prop/direct/>
SELECT
    ?wikidataEntity ?タイトル (LANG(?タイトル) AS ?言語タグ)
WHERE {
    # 例: アニメ映画シリーズ「君の名は。 your name.」
    <https://mediaarts-db.artmuseums.go.jp/id/C413599> schema:identifier ?メディア芸術データベースID .
    SERVICE <https://query.wikidata.org/sparql> {
        # wdt:P7886 はWikidataでメディア芸術データベースのID(URI)を示すプロパティ
        ?wikidataEntity wdt:P7886 ?メディア芸術データベースID ;
                        rdfs:label ?タイトル .
    }
}
                    

→SPARQLクエリサービスで実行する

全文検索

本SPARQLエンドポイントは、Amazon Neptuneの拡張機能を利用した全文検索クエリに対応しています。以下の全文検索用パラメータをSERVICE句を用いて指定することで実行できます。

プロパティ	値
neptune-fts:endpoint	"https://vpc-mediaarts-db-qaymrmtqbprlhmqq33a2ncf4ke.ap-northeast-1.es.amazonaws.com"
neptune-fts:queryType	全文検索のクエリ種別。次のいずれか1つを指定します。 "simple_query_string", "match", "prefix", "fuzzy", "term", "query_string"
neptune-fts:query	実行するクエリ文字列。
neptune-fts:field	検索対象のプロパティ。
neptune-fts:maxResults	検索結果の最大取得数。省略時は10,000になります。
neptune-fts:return	検索結果のリソースのURIがバインドされる変数。

• 接頭辞「neptune-fts:」は名前空間名「 http://aws.amazon.com/neptune/vocab/v01/services/fts#」を表します。
• SERVICE句のエンドポイントには neptune-fts:search を指定します。
• いずれも主語は neptune-fts:config を指定します。
• 各パラメータの仕様の詳細はAmazon Neptuneの資料をご参照ください。
  https://docs.aws.amazon.com/neptune/latest/userguide/full-text-search-parameters.html

クエリ4では、ラベルに「魔法」と「戦」の両方を含むリソースを取得する全文検索クエリを実行しています。クエリ種別 query_string は、ANDやORなどの演算子を含む構文を使うことで、より複雑な検索条件を指定することができます。

クエリ4

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
PREFIX neptune-fts: <http://aws.amazon.com/neptune/vocab/v01/services/fts#>
SELECT ?リソース ?ジャンル ?ラベル
WHERE {
  SERVICE neptune-fts:search {
    neptune-fts:config neptune-fts:endpoint "https://vpc-mediaarts-db-qaymrmtqbprlhmqq33a2ncf4ke.ap-northeast-1.es.amazonaws.com" .
    neptune-fts:config neptune-fts:field rdfs:label .
    neptune-fts:config neptune-fts:queryType "query_string" .
    neptune-fts:config neptune-fts:query '\"魔法\" AND \"戦\"' .
    neptune-fts:config neptune-fts:return ?リソース .
  }
  ?リソース schema:genre ?ジャンル ;
            rdfs:label ?ラベル .
}
                    

→SPARQLクエリサービスで実行する

制限